Notepad++ 7.6 & new Plugins Admin



  • Version 7.6 with its shining new Plugins Admin module just came out.
    Check here for more information :
    https://notepad-plus-plus.org/news/notepad-7.6-released.html



  • Notepad++ v7.6 (64-bit)
    Build time : Nov 13 2018 - 00:12:05
    Path : C:\Program Files\Notepad++\notepad++.exe
    Admin mode : ON
    Local Conf mode : OFF
    OS : Windows 7 (64-bit)
    Plugins : none

    plugins in menubar not shown or at int. never loaded any plugins
    and also
    settings > import > import plugins (s)
    not working



  • Hi @donho ,

    I’ve tested the x86 version and have several remarks:

    1. Not related to the new release itself but - For some reason when you go to https://notepad-plus-plus.org/news/ the new 7.6 release is not shown. The same is true when you go to https://notepad-plus-plus.org/ - no 7.6 there.

    2. After install there is still sub-folder plugins in Notepad++ install folder (it contains only the disabled sub-folder). That is no more needed, correct me if I’m wrong.

    3. I don’t know if it is because of me using Wine but after install, the default plugins that come with Notepad++ package (DSpellCheck, MimeTools, etc.) go into %MY_USER_FOLDER%\AppData\Local\Notepad++\plugins\… and those are not loaded by Notepad++. It is as if Notepad++ doesn’t use that path to look for plugins. When I installed several plugins through PluginAdmin those were put in folder %MY_USER_FOLDER%\Local Settings\Application Data\Notepad++\plugins\… and are loaded by Notepad++ successfully.

    4. After installing several plugins through PluginAdmin I noticed that the zip packages remain in %MY_USER_FOLDER%\Temp . Those are better to be removed after install.

    5. The search field of PluginAdmin dialog window is called Research. Is it a typo? Sounds a bit strange.

    6. Now that the plugins are installed under %MY_USER_FOLDER%\ it would be good to ask the user if he/she wants to install the selected plugins for him/her-self or for all users using the computer. This way it won’t be necessary to install the same plugins for each and every user that would need them on the same machine.

    Thank you for the new release much appreciated.



  • @gurikbal-singh

    Try to follow the procedure described in this page:
    https://notepad-plus-plus.org/news/notepad-7.6-released.html

    for, at least, 1 of your plugins

    I had the same problem (“plugins” item not showing in the menu of Notepad++)… did the “moving” of the plugins directories to their new “home” in
    %LOCALAPPDATA%\Notepad++\plugins\
    and done!

    PS: sorry about my English.



  • @pnedev

    i can confirm point 3. on wine

    in windows %HOMEPATH%\Local Settings is a localized system/administrator symlink to the folder %HOMEPATH%\Appdata\Local, used for legacy installers to access a user account while in administrator mode

    in wine %HOMEPATH%\Local Setting is a physical, separate folder, so the files written by the installer are not put in the target folder %HOMEPATH%\Appdata\Local where expected after the install



  • @donho

    Issues with a local installation of Notepad++ (created by Npp installer)

    1. File nppPluginList.dll is stored in a folder in the user profile of the user who has installed/updated Npp. Thus other users on the same computer have no plugin list.
    2. Except the standard plugins installed with Npp installer, already installed plugins are left in Npp install dir, thus they are not available in Npp Plugins menu.
    3. Plugin Admin displays plugins in an unsorted list.

    The most important is 1., it should be fixed ASAP.

    To mitigate the impact of 2. I wrote a batch script that copies the DLL and companion files of all Notepad++ plugins found in the old Notepad++ plugin directory to the new location of this directory.

    Save the following code as MigrateNppPlugins.cmd to an arbitrary directory of your harddisk and execute it.

    @echo off & setlocal
    
    ::***************** Base configuration ******************
    set "Npp32BitDir=%ProgramFiles(x86)%\Notepad++"
    set "NppNativeDir=%ProgramFiles%\Notepad++"
    ::*******************************************************
    
    
    ::Search installation directory of Notepad++
    set "NppDir="
    
    for %%a in ("%Npp32BitDir%" "%NppNativeDir%") do (
      if exist "%%~a\notepad++.exe" set "NppDir=%%~a"
    )
    
    if "%NppDir%" equ "" (
      echo Notepad++ directory not found. If you are sure that Notepad++ is installed
      echo on this system please load this script in a text editor and set one of the
      echo variables in lines 4 or 5 to the correct installation directory.
      exit /b 1
    )
    
    
    ::Display intro screen
    cls
    
    echo *******************************************************************************
    echo.
    echo   This script copies the DLL and companion files of all Notepad++ plugins
    echo   found under
    echo.
    echo     %NppDir%\plugins
    echo.
    echo   to the new plugin folder of Notepad++ v7.6 under
    echo.
    echo     %LocalAppData%\Notepad++\plugins
    echo.
    echo.
    echo   Please note
    echo   -----------
    echo   This script uses a generic algorithm to do this task. There may be files
    echo   and/or directories left at the present location which you have to copy
    echo   manually to the new location noted above.
    echo.
    echo *******************************************************************************
    echo.
    echo.
    set "KbInput="
    set /p "KbInput=Press ENTER to continue and E+ENTER to exit: "
    echo.
    echo.
    
    if /i "%KbInput%" equ "E" exit /b 0
    
    
    ::Copy plugins and companion files to %LocalAppData%\Notepad++\plugins
    for %%a in ("%NppDir%\plugins\*.dll") do (
      echo.
      echo ===============================================================================
      echo Processing plugin %%~na
      echo ===============================================================================
      
      ::Copy plugin DLL file
      echo.
      echo ---- Copy file ----
      echo "%%~a"
      echo to
      echo "%LocalAppData%\Notepad++\plugins\%%~na"
      
      md "%LocalAppData%\Notepad++\plugins\%%~na" 1>NUL
      copy "%%~a" "%LocalAppData%\Notepad++\plugins\%%~na" 1>NUL
      
      ::Copy directory under "plugins" related to plugin
      dir /b /a:d "%NppDir%\plugins\%%~na" 1>NUL 2>NUL && (
        echo.
        echo ---- Copy directory ----
        echo "%NppDir%\plugins\%%~na"
        echo to
        echo "%LocalAppData%\Notepad++\plugins\%%~na\%%~na"
        
        md "%LocalAppData%\Notepad++\plugins\%%~na\%%~na" 1>NUL
        xcopy /eikqy "%NppDir%\plugins\%%~na\*.*" "%LocalAppData%\Notepad++\plugins\%%~na\%%~na" 1>NUL
      )
    
      ::Copy files under "plugins\doc" related to plugin
      dir /b /a:-d "%NppDir%\plugins\doc\%%~na*.*" 1>NUL 2>NUL && (
        echo.
        echo ---- Copy files ----
        echo "%NppDir%\plugins\doc\%%~na*.*"
        echo to
        echo "%LocalAppData%\Notepad++\plugins\%%~na\doc"
    
        md "%LocalAppData%\Notepad++\plugins\%%~na\doc" 1>NUL
        copy "%NppDir%\plugins\doc\%%~na*.*" "%LocalAppData%\Notepad++\plugins\%%~na\doc" 1>NUL
      )
    
      ::Copy directory under "plugins\doc" related to plugin
      dir /b /a:d "%NppDir%\plugins\doc\%%~na" 1>NUL 2>NUL && (
        echo.
        echo ---- Copy directory ----
        echo "%NppDir%\plugins\doc\%%~na"
        echo to
        echo "%LocalAppData%\Notepad++\plugins\%%~na\doc\%%~na"
    
        md "%LocalAppData%\Notepad++\plugins\%%~na\doc\%%~na" 1>NUL
        xcopy /eikqy "%NppDir%\plugins\doc\%%~na\*.*" "%LocalAppData%\Notepad++\plugins\%%~na\doc\%%~na" 1>NUL
      )
      
      echo.
      echo.
    )
    
    pause
    
    exit /b 0
    

    Issues with Plugin Manager plugin

    This is addressed to the Plugin Manager team (e.g. @chcg) only.

    1. Download of plugin list fails.
    2. Settings dialog contains only checkbox “Notify of plugin updates at startup” and input field “Check for plugin updates every”.
    3. Closing settings dialog causes crash of Notepad++.


  • @pnedev

    Not related to the new release itself but - For some reason when you go to https://notepad-plus-plus.org/news/ the new 7.6 release is not shown. The same is true when you go to https://notepad-plus-plus.org/ - no 7.6 there.

    It’s due to the cach of notepad-plus-plus.org site, I will make it work ASAP.

    After install there is still sub-folder plugins in Notepad++ install folder (it contains only the disabled sub-folder). That is no more needed, correct me if I’m wrong.

    True. It will be removed in the next release.

    I don’t know if it is because of me using Wine but after install, the default plugins that come with Notepad++ package (DSpellCheck, MimeTools, etc.) go into %MY_USER_FOLDER%\AppData\Local\Notepad++\plugins\… and those are not loaded by Notepad++. It is as if Notepad++ doesn’t use that path to look for plugins. When I installed several plugins through PluginAdmin those were put in folder %MY_USER_FOLDER%\Local Settings\Application Data\Notepad++\plugins\… and are loaded by Notepad++ successfully.

    I have tested the installer again, works to me. It should be WINE issue only.

    After installing several plugins through PluginAdmin I noticed that the zip packages remain in %MY_USER_FOLDER%\Temp . Those are better to be removed after install.

    Nice catched - will be done in next release.

    The search field of PluginAdmin dialog window is called Research. Is it a typo? Sounds a bit strange.

    “Search” in French word is “Rechercher”, so it’s my Frenglish - will be fixed in the next version.

    Now that the plugins are installed under %MY_USER_FOLDER%\ it would be good to ask the user if he/she wants to install the selected plugins for him/her-self or for all users using the computer. This way it won’t be necessary to install the same plugins for each and every user that would need them on the same machine.

    Let’s keep the current folder structure so far. We will see if such need comes.



  • @OverlordBR
    @gurikbal-singh

    the problem of not seeing any plugins always seems to happen if you install np++ with the option “don’t use %appdata%” selected

    it seems that even if the doLocalConf.xml exists, and the plugins are present in the np++ plugin folder within the program folder, np++ is searching for the plugins at %LOCALAPPDATA%\Notepad++\plugins

    so if %LOCALAPPDATA%\Notepad++\plugins was empty before installation (same folder as %USERPROFILE%\AppData\Local\Notepad++\plugins) you will not see any plugins



  • additional info (i’ve just tested it):

    this behavior is triggered by installing np++ within C:\Program Files with “don’t use %APPDATA%” selected

    if i install np++ (same installer) anywhere else like C:\Notepad++, the doLocalConf.xml triggers correctly to use the plugins folder within the program folder and not from %LOCALAPPDATA%

    just crosschecked:
    i’ve put the portable version npp.7.6.bin.zip manually into the Program Files folder and the plugins dissapear.
    as soon as you move this same portable version folder out of Program Files, eg. to the desktop, and start Notepad++.exe all plugins are shown



  • @donho would be good to have the information about the plugin folder changes and the manual movement from the webpage
    also in the changelog.



  • @dinkumoil
    ad 1, Can’t confirm the issue with plugin manager. The list is downloaded for me and also the setting dialog is ok.
    ad 2, What do you see under the Information field? For me it is:

    C:\Users\XXX\AppData\Roaming\Notepad++\plugins\Config
    Plugins in user’s AppData directory are enabled. Remove the allowAppDataPlugins.xml file from the Notepad++ directory to disable.

    ad 3, Don’t see the crash, maybe for me the behaviour is ok, as PM was already installed before

    4, What I see is that the installed plugins are no longer found, because there is no adaptation to the new location under %LOCALAPPDATA% yet.



  • @Meta-Chuh right thing
    but i clean that directory before install because 7.5.9 was installed



  • @chcg

    Solved it. I had only copied all plugin DLL files to the new plugins directory in %LocalAppData%, thus there had been plugin DLL files in the old plugins directory too. Removing these solved the problem.



  • I have created a Gist with an updated version of my migration script above.

    Link: https://gist.github.com/dinkumoil/cb65c277dda5158174f4849e08ba872f



  • @donho Is it expected/intended behaviour that the plugin admin is not available for the zip/7z package?



  • @chcg

    Seems like this could be the answer. See the Edit.





  • Up till this version I had both the 32-bit and the 64-bit N++ installed with their plugins installed in C:\Program Files (x86)\Notepad++\plugins and C:\Program Files\Notepad++\plugins respectively. The configuration files were shared and located in C:\Users\%USERNAME%\AppData\Roaming\Notepad++.
    This seems no longer possible as plugins are now loaded from C:\Users\%USERNAME%\AppData\Local\Notepad++\plugins for both 32-bit and 64-bit N++.



  • @gurikbal-singh

    settings > import > import plugins (s)
    not working

    It’ll be fixed in the next release.



  • @dinkumoil

    File nppPluginList.dll is stored in a folder in the user profile of the user who has installed/updated Npp. Thus other users on the same computer have no plugin list.
    Except the standard plugins installed with Npp installer, already installed plugins are left in Npp install dir, thus they are not available in Npp Plugins menu.
    Plugin Admin displays plugins in an unsorted list.

    The most important is 1., it should be fixed ASAP.

    Why the most important is 1 ?
    OTOH, people will be able to download NppPluginList.dll in the future.


Log in to reply